Ballerina について

Ballerina とは

Ballerina は、 Cloud Native Programming Language を謳うプログラミング言語です。

Ballerina は、現在の micro service, network end point というソフトウェア開発を強く意識したプログラミング言語です。思想として、クラウド上での micro service を実現できるように、サーキットブレーカーやロードバランシング、エラーハンドリングなど、複数のプロセスが連動するような場合に必須となる機能を実装を言語層で容易におこなえることを特徴としています。

Ballerina の Hello World

Balerina は、基本的に micro service として単一のサービスを実装したエンドポイントを組合せてソフトウェアを構築することを想定しています。このため、 Hello World の例も、 "Hello World" を出力するサービスとそれを受け取るクライアントで表現されることが多いようです。

"Hello World" サービスの実装例

 import ballerina/http;

service hello on new http:Listener(9090) {
    resource function sayHello(http:Caller caller, http:Request req) returns error? {
        check caller->respond("Hello World");
    }
}

service は、そのプログラムで実装するサービスを定義するシンタックスになります。上記の例では、 hello というサービスを httpプロトコルで、Port: 9090 にて提供することを宣言しています。 resource は、そのサービスが提供する機能の定義をしています。 caller は、このサービスを呼び出したクライアントを意味するオブジェクトとなっており、上記のプログラムでは、caller に対して "Hello World" を返却するというロジックになっています。今回の場合、サービスは http として実装しており、 caller も http の Caller として定義しているので、返却先は呼び出した http client で、返却データは http の Response Bodyとして通知されます。

対応する http client の実装例

import ballerina/http;
import ballerina/io;

public function main() returns @tainted error? {
    http:Client clientEp = new ("http://localhost:9090");
    http:Response resp = check clientEp->get("/hello/sayHello/");

    string payload = check resp.getTextPayload();

    io:println(payload);
}

clientEp は "http://localhost:9090" に対し要求を行う http client として定義しています。上記のプログラムでは、 clientEp に対して、 "GET /hello/sayHello/" という RestAPI を実行して、その通信結果を resp に受けています。 RestAPI の処理結果は http Response Body に含まれるので、 resp.getTextPayload() にて取得して、標準出力へ出力しています。

汚染されているリソースという考えかた

Ballerina 特有の考え方に、外部から受けとるデータは汚染されているという考え方があります。これは、 Ballerina で実装するプログラムは基本的に network end point となることを想定しているため、SQLインジェクションなど、悪意のあるアクセスはありえるものと想定しているためです。

このため、 Ballerina では、関数を定義するときに汚染されていない (検証済みの)データしか受け取れないように宣言 (引数宣言時に @untinted を付与する)し、呼び出し側では、汚染されていなことを検証したこと示す (<@untinted>でキャストする)ことで、データの安全性を担保するしくみを持っています。

以下に、例題プログラムを示します。

import ballerina/http;
import ballerina/io;
import ballerina/lang.'float;

public function main(string... args) returns @tainted error? {
    http:Client sunriseApi = new("http://api.sunrise-sunset.org");

    if (args.length() != 2 ) {
        io:println("Invalid argument.");
    }

    float|error lat = 'float:fromString(args[0]);
    float|error lng = 'float:fromString(args[1]);

    if (lat is float && lng is float) {
         http:Response sunriseResp = check sunriseApi-> get("/json?lat=" + <@untinted> lat.toString() + "&lng=" + <@untainted>lng.toString());
         json sunrisePayload = check sunriseResp.getJsonPayload();
         io:println(sunrisePayload);
    } else {
        io:println("Invalid argument.");
    }
}